Rig mit Arduino

Darf ich vorstellen: Mein neues Rig mit Arduino (Uno R3), welches heute seinen Jungfernflug gehabt hat (sorry für die Bildqualität, meine Spiegelreflex hasst Kunstlicht bei Videos). Mit Ausnahme von Aufsteckplatine Mäuseklavier und Akku stammen alle elektrischen Komponenten aus einem Arduino Einsteigerset. Gesamtgewicht mit Kamera knapp 480g.

Das Rig besteht aus 3mm dicken Plastikplatten, die ich bei Obi gefunden haben. Ich bin schwer begeistert von dem Material, da es stabil ist, gleichzeitig etwas flexibel und vor allem sehr einfach mit dem Cutter zu schneiden. Einmal mit Lineal anreißen, dann zwei Schnitte ohne Lineal nachziehen, fertig. Leider habe ich den Aufkleber entsorgt, deshalb kann ich zur Zeit nicht mit dem Namen dienen. Das Rig wurde von der Größe exakt auf meine Kamera angepasst, oben befindet sich eine leicht überdimensionierte Halteplatte für die Elektronik. Da ich da noch ein bisschen experimentieren will, alles in offener Bauweise. Die Platten sind mit Heißkleber verklebt und mit Gewebeklebeband verstärkt. Ein paar sanfte Abstürze hat es heute problemlos hingenommen.

Die Neigung wird über einen Miniservo gesteuert. Da der viel zu schnell drehte, habe wird der jetzt nur noch in 1°-Schritten weitergedreht, wodurch sich ein Aufschaukeln wirksam verhindern lässt. Über das Mäuseklavier kann ich festlegen, ob die Kamera noch zwei zusätzliche Positionen anfahren soll.

Die Drehung wird durch einen kleinen Schrittmotor erledigt, welcher mit Klettband und einem Kabelbinder befestigt ist, dadurch kann ich auf den Schwerpunkt noch etwas Einfluss nehmen. Im Schrittmotor befindet sich ein Getriebe, welches so viel Widerstand aufbringt, dass ich in den drehfreien Zeiten keine Spannung zum Halten der Position anlegen muss. Der Motor gefällt mir so gut, dass ich eventuell den seitlichen Servo ebenfalls durch einen Schrittmotor ersetze.

Alle Verbraucher werden über das Arduino Board mitversorgt, so dass ich nur eine Spannungsversorgung benötige.

Die Kamera wird über eine IR-Led ausgelöst, welche ebenfalls vom Arduino gesteuert wird.

Kann alles in allem noch nicht mehr als das Aurico, aber: Selbstgemacht :-O Und ich kann vor hier aus weiter basteln. Angedacht sind das Überspringen von bestimmten Drehpositionen oder die automatische Ausrichtung auf ein vorher ausgewähltes Ziel. Mal schauen.

Der Motor ist ein 28BYJ-48 mit einem ULN2003-Board. Einfach bei Ebay weltweit suchen, die bekommt man fast geschenkt.

Hier der -unaufgeräumte- Code:

#include <Servo.h>
#include <multiCameraIrControl.h>




const boolean DEBUG = false;




// Wo sind die Pins angeschlossen?
const int stepperPin0 = 5; 
const int stepperPin1 = 4; 
const int stepperPin2 = 3; 
const int stepperPin3 = 2;
const int servoPin = 10;




// Neigungswinkel
const int neigungEins = 170;
const int neigungZwei = 135;
const int neigungDrei = 105;


const int neigungZweiPin = A5;
const int neigungDreiPin = A4;






// Position 4096 == komplette Umdrehung
int _position = 0;




// Servo initialisieren
Servo kapServo;




// Kamera initialisieren
Pentax kapKamera(11);




// Hilfsfunktion für drehen der Pins
void setPin(int _pin0, int _pin1, int _pin2, int _pin3) {
  digitalWrite(stepperPin0, _pin0);
  digitalWrite(stepperPin1, _pin1);
  digitalWrite(stepperPin2, _pin2);
  digitalWrite(stepperPin3, _pin3);  
}




// Hilfsfunktion zur Vorbereitung der Input-Pins
void initInput(int _pin) {
  pinMode(_pin, INPUT);
  digitalWrite(_pin, HIGH);
}




// Kamera uslösen
void knipsen() {
  setPin(LOW,LOW,LOW,LOW);
  
  // 2 Sekunden auspendeln lassen
  delay(2000);
  
  // Hier kommt das Vögelchen!
  kapKamera.shutterNow();
   
  // 1 Sekunde Belichtungszeit
  delay(1000);
}




// Servo in bestimmte Position fahren
void neigen(int nach) {
  kapServo.attach(servoPin);  
  
  int von = kapServo.read();
  int richtung = -1;
  
  if(nach > von) {
    richtung = 1;
  }
  
  while(von != nach) {
    von = von + richtung;
    kapServo.write(von); 
    delay(20);  
  }
  
  kapServo.detach();
}




void setup() 
{ 
  // Stepper initalisieren
  pinMode(stepperPin0, OUTPUT);  
  pinMode(stepperPin1, OUTPUT);  
  pinMode(stepperPin2, OUTPUT);  
  pinMode(stepperPin3, OUTPUT);


  // Mäuseklavier initialisieren
  initInput(A0);
  initInput(A1);
  initInput(A2);
  initInput(A3);
  initInput(A4);
  initInput(A5);
  initInput(8);
  initInput(9);
 
  // Kamerhalterung für 5 Sekunden ausklappen 
  neigen(110);
  delay(5000);
 
  // Und ab in Standardposition
  neigen(neigungEins); 
  delay(1000);    
} 




void loop() 
{ 
  // Jede 32ste Umdrehung etwas tun....
  if(_position % 128 == 0) {
    // Erste Position knipsen
    neigen(neigungEins);
    knipsen();
    
    // Wenn gewünscht, zweite Position knipsen
    if(!digitalRead(neigungZweiPin)) {
      neigen(neigungZwei);
      knipsen();      
    }
    
    // Wenn gewünscht, dritte Position knipsen
    if(!digitalRead(neigungDreiPin)) {
      neigen(neigungDrei);
      knipsen();      
    }    
  }
  
  // Motor drehen
  if(!DEBUG) {
    switch(_position % 8){ 
      case 0: 
        setPin(LOW,LOW,LOW,HIGH);
      break;  
      case 1: 
        setPin(LOW,LOW,HIGH,HIGH);
      break;  
      case 2: 
        setPin(LOW,LOW,HIGH,LOW);
      break;  
      case 3: 
        setPin(LOW,HIGH,HIGH,LOW);
      break;  
      case 4: 
        setPin(LOW,HIGH,LOW,LOW);
      break;  
      case 5: 
        setPin(HIGH,HIGH,LOW,LOW);
      break;  
      case 6: 
        setPin(HIGH,LOW,LOW,LOW);
      break;  
      case 7: 
        setPin(HIGH,LOW,LOW,HIGH);
      break;  
      default: 
        setPin(LOW,LOW,LOW,LOW); 
      break;  
      }
    }


  _position++;
  
  if(_position >= 4096) {
    _position = 0;
    
  }
  
  
  delay(10); 
}

Die IR Bibliothek findest Du hier .

Die Achse ist relativ weich, die ließ sich problemlos freihändig mit einem 2mm-Stahlbohrer durchlöchern. Ich hab dann ein wenig Heißkleber aufgetragen, um das Spiel zu minimieren und ein Alurohr mit 5mm Innendurchmesser aufgesetzt. Dann noch mit einem Splint gesichert. Bei mir steckt dieses Alurohr dann wiederum in einem Gewebeschlauch, der gleichzeitig das Kreuz des Pivacet hält.

Bin gestern noch ein Stündchen geflogen, die ruhigen Bewegungen machen sich sehr bezahlt. Ich habe fast keinen verwacklungsbedingten Ausschuss mehr.

Gruß, Marcel

Ich hab mittlerweile vom Chinamann einen erheblich kleineren Arduino Nano bekommen (12 EUR mit Versand). Gestern testweise mal einen kleinen Servo (Towerpro SG90) bei 9V Eingangsspannung mit über den Spannungsregler laufen lassen, hat ohne fühlbare Temperaturerhöhung einwandfrei geklappt. Bin mal gespannt, ob er auch die Spannung für den Stepper frisst.